@echo off
echo NVIDIA のディスプレイドライバのあるフォルダに配置して、実行すると
echo Windows 2000向けの INF ファイルを元の INF ファイルと置き換えて生成します。
ECHO なお、INFDATABAK にバックファイルを作成します。
ECHO When set this file in nVidia display driver folder, and execute it,
ECHO It will create INF File for Windows which replace to original inf.
ECHO And backup are created in INFDATABAK.
ECHO              by BlackWingCat. (tested v331 driver) 
PAUSE
setlocal enabledelayedexpansion 
IF NOT EXIST INFDATABAK MD INFDATABAK
IF EXIST INFLIST.txt ( del INFLIST.txt )
FOR /F %%I IN ('DIR/B/ON *.INF')  DO (
 ECHO %%I >> INFLIST.txt
 IF NOT EXIST INFDATABAK\%%I COPY %%I INFDATABAK\%%I
 DEL %%I
 SET CNT=0
 SET CNT2=0
 FOR /F "eol=, delims=" %%J IN ( INFDATABAK\%%I ) DO (
   IF "%%J" == "AddReg = nv_commonCoinstaller_addreg" ( 
      SET /A CNT = !CNT! + 1
   ) ELSE IF "%%J" == "CopyFiles = nv_coinstaller_copyfiles" ( 
      SET /A CNT = !CNT! + 1
   ) ELSE IF "%%J" == "[NVIDIA_Devices.NTx86.5.1]" ( 
     ECHO [NVIDIA_Devices]>> %%I
     SET /A CNT2 = !CNT2! + 1
   ) ELSE (
     ECHO %%J>>%%I
   )
 )
 ECHO 変更 %%I [ !CNT! / !CNT2! ]
)
endlocal
pause